Error with the polstatus?

epsilon · Post by **epsilon** » Thu Apr 01, 2010 4:56 pm

It has been working fine and I have done no changes to it, but once we passed 320 players online I started getting this message on the shard page here at www.polserver.com

Code: Select all

Query failed: Out of range value adjusted for column 'shard_last_users' at row 1

This is my polstatus script:

Code: Select all

/* $Id$
 *
 */

use uo;
use util;
use http;

ENUM SERVER_STATS
	CPU		:= "",
	RAM		:= "",
	HDD		:= "",
	OS		:= "",
	CONNECTION	:= "",
	LOCATION	:= "",
	TIMEZONE	:= ""
ENDENUM

Program HTMLPage()
	if ( QueryParam("XML") )
		OutputXML();
	else
		OutputHTML();
	endif
	
	return 1;
endprogram

function OutputXML()
	WriteHTML("<CONTENT>");	
	var core_ref := POLCore();
	WriteHTML("<POL>");
	WriteHTML("<VERSION>"+core_ref.verstr+"</VERSION>");
	WriteHTML("<ACCOUNTS>"+ListAccounts().Size()+"</ACCOUNTS>");
	WriteHTML("<TLI>"+core_ref.itemcount+"</TLI>");
	WriteHTML("<MOBILEAMT>"+core_ref.mobilecount+"</MOBILEAMT>");
	WriteHTML("<PLAYERAMT>"+EnumerateOnlineCharacters().Size()+"</PLAYERAMT>");
	WriteHTML("<LOAD>"+core_ref.sysload+"%</LOAD>");
	WriteHTML("<UPTIME>"+FormatSeconds(core_ref.uptime)+"</UPTIME>");
	WriteHTML("<RX>"+FormatBytes(core_ref.bytes_received)+"</RX>");
	WriteHTML("<TX>"+FormatBytes(core_ref.bytes_sent)+"</TX>");
	WriteHTML("</POL>");
	
	WriteHTML("</CONTENT>");
	
	return 1;
endfunction

function OutputHTML()
	WriteHTML("<HTML>");
	WriteHTML("<HEAD>");
	WriteHTML("<TITLE>POL Internal Web Server</TITLE>");
	WriteHTML("<LINK REL='stylesheet' TYPE='text/css' HREF='/stylesheets/main.css'>");
	WriteHTML("</HEAD>");

	WriteHTML("<BODY>");

	WriteHTML("<DIV ID='container'>");

	WriteHTML("<DIV ID='header'></DIV>");


	WriteHTML("<DIV ID='content'>");

	WriteHTML("<TABLE WIDTH='400' CELLSPACING='1' CELLPADDING='2'>");
	WriteHTML("</TABLE>");

	WriteHTML("<BR><BR>");

	var core_ref := POLCore();
	WriteHTML("<TABLE WIDTH='400' CELLSPACING='1' CELLPADDING='2'>");
	WriteHTML("<TR><TH COLSPAN='2' ALIGN='LEFT'><B>Shard Information</B></TH></TR>");
	WriteHTML("<TR><TD>POL Version:</TD><TD>"+core_ref.verstr+"</TD></TR>");
	WriteHTML("<TR><TD>Accounts:</TD><TD>"+ListAccounts().Size()+"</TD></TR>");
	WriteHTML("<TR><TD>Top Level Items:</TD><TD>"+core_ref.itemcount+"</TD></TR>");
	WriteHTML("<TR><TD>Mobile Count:</TD><TD>"+core_ref.mobilecount+"</TD></TR>");
	WriteHTML("<TR><TD>Player Count:</TD><TD>"+EnumerateOnlineCharacters().Size()+"</TD></TR>");
	WriteHTML("<TR><TD>Load:</TD><TD>"+core_ref.sysload+"%</TD></TR>");
	WriteHTML("<TR><TD>POL Uptime:</TD><TD>"+FormatSeconds(core_ref.uptime)+"</TD></TR>");
	WriteHTML("<TR><TD>Bytes Received:</TD><TD>"+FormatBytes(core_ref.bytes_received)+"</TD></TR>");
	WriteHTML("<TR><TD>Bytes Sent:</TD><TD>"+FormatBytes(core_ref.bytes_sent)+"</TD></TR>");
	WriteHTML("</TABLE>");

	WriteHTML("</DIV>");

	WriteHTML("<DIV ID='footer'>");
	WriteHTML("<P>Copyright &copy; 2006-2008 - POL Development Team.</P>");
	WriteHTML("</DIV>");
	WriteHTML("</DIV>");
	WriteHTML("</BODY>");
	WriteHTML("</HTML>");
	
	return 1;
endfunction


function FormatSeconds(seconds)
	CONST SEC_PER_HOUR := 3600.0;
	CONST SEC_PER_DAY := 86400.0;
	CONST SEC_PER_WEEK := 604800.0;

	var formatted := "";

	if ( seconds >= SEC_PER_WEEK )
		var weeks := CInt(seconds/SEC_PER_WEEK);
		if ( weeks > 1 )
			formatted := CStr(weeks) + " weeks, ";
		else
			formatted := "1 week, ";
		endif

		seconds := seconds - (weeks * SEC_PER_WEEK);
	endif

	if ( seconds >= SEC_PER_DAY )
		var days := CInt(seconds/SEC_PER_DAY);
		if (days > 1)
			formatted := formatted + CStr(days) + " days, ";
		else
			formatted := formatted + "1 day, ";
		endif
		seconds := seconds - (days * SEC_PER_DAY);
	endif

	if ( seconds >= SEC_PER_HOUR )
		var hours := CInt(seconds/SEC_PER_HOUR);
		if (hours > 1)
			formatted := formatted + CStr(hours) + " hours, ";
		else
			formatted := formatted + " 1 hour, ";
		endif
		seconds := seconds - (hours * SEC_PER_HOUR);
	endif

	var minutes := CInt(seconds/60.0);
	if ( minutes )
		formatted := formatted + CStr(minutes) + " minutes, ";
		seconds := seconds - (minutes * 60);
	endif
	if ( seconds )
		if ( seconds == 1 )
			formatted := formatted + " 1 second";
		else
			formatted := formatted + CStr(seconds) + " seconds";
		endif
	endif

	return formatted;
endfunction

function FormatBytes(bytes)
	CONST BYTES_IN_KILO	:= 1024.0;
	CONST BYTES_IN_MEG	:= 1048576.0;

	var mb := CDbl(bytes) / BYTES_IN_MEG;
	var type := "MB";

	if ( mb < 1.0 )
		mb := CDbl(bytes) / BYTES_IN_KILO;
		type := "KB";

		if ( mb < 1.0 )
			mb := bytes;
			type := "bytes";
		endif
	endif

	return CStr(mb)+" "+type;
endfunction

Post by **Turley** » Fri Apr 02, 2010 1:31 am

fixed
problem was a too small numeric type (tinyint) 0-255
i changed it to smallint 0-65535 should be enough

epsilon · Post by **epsilon** » Fri Apr 02, 2010 1:35 am

Turley wrote:fixed
problem was a too small numeric type (tinyint) 0-255
i changed it to smallint 0-65535 should be enough

Thanks

Is there any limit to the amount of players pol will support? I peak at around 330 currently on my shard without lag. And some normal scripts like my cooking script started to get warnings like "runaway" scripts (when it looks for fire or oven) because so many ppl are using it.

Post by **Turley** » Fri Apr 02, 2010 2:38 am

Nope runaways have nothing to do with onlinechars. It just gives you a warning if one single script runs too long without sleep.
For example your cooking oven search looks like:

ForEach item in ListItemsNearLocation(....)
if (item.objtype==oven)
....
endif
EndForEach

imagine you have several hundreds items near that location then you get a warning about runaway cause the loop runs and runs and runs...

change this loop to:
ForEach item in ListItemsNearLocation(....)
if (item.objtype==oven)
....
endif
SleepMS(2); //runaway prevention
EndForEach

this way you prevent the runaway without loosing noticable performance.

More info about runaways: http://docs.polserver.com/pol099/guides ... erformance

epsilon · Post by **epsilon** » Fri Apr 02, 2010 3:41 am

Turley wrote:Nope runaways have nothing to do with onlinechars. It just gives you a warning if one single script runs too long without sleep.
For example your cooking oven search looks like:

ForEach item in ListItemsNearLocation(....)
if (item.objtype==oven)
....
endif
EndForEach

imagine you have several hundreds items near that location then you get a warning about runaway cause the loop runs and runs and runs...

change this loop to:
ForEach item in ListItemsNearLocation(....)
if (item.objtype==oven)
....
endif
SleepMS(2); //runaway prevention
EndForEach

this way you prevent the runaway without loosing noticable performance.

More info about runaways: http://docs.polserver.com/pol099/guides ... erformance

Yeah, the thing is that when I had under like 250 players I never got any runaway scripts. But when I went over that the normal cooking script gave some runaway warning. It's not a biggie I know and it's easy prevent with some sleeptime (which I already added). I was just curious about the thing that this script and other scripts got runaway warnings when the shard got many players on.

So the polcore can handle about unlimited players as long as there is enough computer resources? I've heard rumours about there being problems after 400 players online and such, just want to investigate if there's any merit to these rumours.

Post by **Turley** » Fri Apr 02, 2010 10:04 am

check the runaway error msg and take a look where it happens in your scripts, my guess is that you have some loops over online chars

Error with the polstatus?

Error with the polstatus?

Re: Error with the polstatus?

Re: Error with the polstatus?

Re: Error with the polstatus?

Re: Error with the polstatus?

Re: Error with the polstatus?